Yayınlanma: 31/10/2018
Güncelleme: 02/11/2024
Bilgisayarda geçici olarak kullanılan klasörler bulunur. Bu klasörleri çeşitli programlar geçici olarak kullanılmak üzere bazı dosyalar oluştururlar.Güncelleme: 02/11/2024
Birçok program geçici oluşturduğu dosyaları işi bittiğinde silerken bazı programlar ise silmez. Klasör gereksiz dosyalarla dolar.
CCleaner gibi programlar bu klasörleri temizleyebilmektedir ancak bu yazıda program kullanmadan bu işi halledeceğiz.
Bu işlem için bat dosyası kullanacağız. BAT dosyalar DOS ortamındaki komutların sıralı yürütmesini sağlar.
Dosyayı oluşturmak için masaüstünde sağ tıklayıp açılan menüden Yeni / Metin belgesi tıklanır.
Dosya adı olarak tempsil.bat adı verilir.
Oluşan dosya üzerinde sağ tıklanıp açılan menüden Düzenle tıklanır.
Eğer Notepad++ kurulu ise Edit with Notepad++ tıklanabilir.
Editörde aşağıdaki kodlar girilir ve dosya kaydedilir.
Bu dosya çift tıklandığında %TEMP% ve C:\Windows\Temp klasörleri içindekiler silinir.
Programların aktif kullandığı dosyalar erişim engelinden dolayı silinmez.
@echo off
REM Geçici olarak kullanılan klasörlerin temizlenmesi
REM Mesut Akcan
REM makcan@gmail.com
REM mesutakcan.blogspot.com
REM 31/10/2018
REM Güncelleme: 02/11/2024
chcp 1254 > nul
call :silKlasor "%TEMP%" "1F"
call :silKlasor "%WINDIR%\Temp" "2F"
call :silKlasor "%WINDIR%\Prefetch" "3F"
color 4F
echo =============
echo İşlem Tamam !
echo =============
pause
exit :: ÇIKIŞ -->
:silKlasor
set "klasor=%~1"
color %~2
echo ============================================================
echo %klasor% klasöründeki tüm dosya ve klasörler silinecek !!!
echo ===== İptal için CTRL+C ======
echo ============================================================
pause
if exist "%klasor%" (
cd /d "%klasor%"
for /f "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
dir /a
)
call :bossatirlar
exit /b
:bossatirlar
echo.
echo.
echo.
exit /b
Kod yapısını kullanarak klasor değişkenine başka klasör yolu belirterek başka klasör içi de temizlenebilir.
