AutoLISP: Kullanıcı girişi sağlayan fonksiyonlar - 2

Bu yazının önceki bölümü: AutoLISP: Kullanıcı girişi sağlayan fonksiyonlar - 1

9) initget Fonksiyonu: Kullanıcı Girdi Kontrolü

initget fonksiyonu, kullanıcıdan alınacak girdilerin kontrolünü sağlar. Bu fonksiyon, getint, getreal, getstring, getpoint, getdist, getangle, getkword gibi kullanıcı girdisi alan fonksiyonlarla birlikte kullanılır. Kullanıcı girdisini belirli kurallara göre sınırlandırmak ve geçerli girdileri tanımlamak için kullanılır.

Kullanımı:

(initget [bit-değeri] [anahtar-kelimeler])

bit-değeri (isteğe bağlı): Girdi kontrolü için kullanılan bit değeridir. Bu değer, kullanıcının girdisini nasıl sınırlandıracağınızı belirler.

Belirli kullanıcı girdisi türlerine izin veren veya vermeyen bir bit kodu. Bitler, 0 ile 255 arasında bir değer oluşturmak için herhangi bir kombinasyonda toplanabilir. bit-değeri belirtilmezse 0(sıfır) varsayılır.

initget Fonksiyonunun Bit Değerleri:

Bit	Değer	Açıklama
0	1	Kullanıcının yalnızca Enter tuşuna basarak yanıt vermesini engeller.
1	2	Kullanıcının 0(sıfır) girerek yanıt vermesini engeller.
2	4	Kullanıcının negatif bir değer girerek yanıt vermesini engeller.
3	8	Kullanıcının geçerli çizim sınırlarının dışında bir nokta girmesine izin verir
4	16	(Şu anda kullanılmıyor)
5	32	Geçici çizgi veya geçici dikdörtgen çizerken kesik çizgiler kullanır.
6	64	getdist fonksiyonuna Z koordinatı girilmesini engeller; bir uygulamanın bu fonksiyonun 2B mesafe döndürdüğünden emin olmasını sağlar
7	128	Diğer kontrol bitlerini ve listelenen anahtar sözcükleri dikkate alarak keyfi girdiye anahtar sözcükmüş gibi izin verir. Bu bit, bit 0'a göre önceliklidir; bit 7 ve 0 ayarlıysa ve kullanıcı Enter tuşuna basarsa, boş bir dize döndürülür.
8	256	Doğrudan mesafe girişine rastgele girişe göre öncelik verir. Harici uygulamalar için, rastgele girdiye varsayılan olarak doğrudan mesafe girdisine göre öncelik verilir. AutoCAD'i kullanıcı girdisini doğrudan mesafe girdisi olarak değerlendirmeye zorlamak istiyorsanız bu biti ayarlayın. Klavyeden yasal nokta girişinin her zaman doğrudan mesafe veya rastgele girişten öncelikli olduğunu unutmayın.
9	512	Bir getpoint veya getcorner çağrısından önce ayarlanırsa, imleç bir katının düzlemsel bir yüzeyinin kenarından geçtiğinde geçici bir UCS oluşturulur. İmleç bir yüzeyin dışına çıktığında geçici UCS sıfırlanır. İmleç farklı bir yüzeyin üzerinden geçtiğinde dinamik olarak yeniden oluşturulur. Nokta alındıktan sonra, dinamik UCS geçerli UCS'ye sıfırlanır. Bu işlevsellik, silindir kenarı gibi düzlemsel olmayan yüzeyler için etkin değildir.
10	1024	getdist, getangle, getorient, getpoint veya getcorner fonksiyonlarını çağırırken, mesafe, açı, yön, nokta veya köşenin Z yönünde orto, polar veya otracking tarafından etkilenmesini istemeyebilirsiniz. Bu fonksiyonlardan herhangi biri çağrılmadan önce bu bitin ayarlanması, Z yönünde orto, polar ve otracking'i geçici olarak devre dışı bırakacaktır. Bu, çoklu çizgi, yay veya daire gibi 2B varlıklar oluşturduğunuzda veya yalnızca 2B dizi oluşturan AutoCAD ARRAY komutunu kullandığınızda kullanışlıdır. Yalnızca 2B komutlarda, 3B noktaların orto Z, polar Z veya otrack Z kullanılarak girilmesine izin vermek kafa karıştırıcı ve hataya açık olabilir.

anahtar-kelimeler (isteğe bağlı): Kullanıcının seçebileceği anahtar kelimeleri içeren bir metin dizisidir. Anahtar kelimeler boşlukla ayrılır.

Anahtar kelimeleri kabul eden işlevler getint, getreal, getdist, getangle, getorient, getpoint, getcorner, getkword, entsel, nentsel ve nentselp'dir.

getstring işlevi, anahtar kelimeleri dikkate almayan tek kullanıcı girişi fonksiyonudur.

Kullanıcı beklenen girdi türünü girmediğinde (örneğin, getpoint için bir nokta) anahtar kelimeler bir sonraki kullanıcı-girdi işlevi çağrısı tarafından kontrol edilir. Kullanıcı girişi listedeki bir anahtar kelimeyle eşleşirse, işlev bu anahtar sözcüğü dize sonucu olarak döndürür. Uygulama anahtar kelimeleri test edebilir ve her biriyle ilişkili eylemi gerçekleştirebilir.

Kullanıcı girişi beklenen bir tür değilse ve bir anahtar kelimeyle eşleşmiyorsa, AutoCAD kullanıcıdan tekrar denemesini ister. initget bit değerleri ve anahtar kelimeler yalnızca bir sonraki kullanıcı girişi işlev çağrısı için geçerlidir.

initget bir kontrol biti ayarlarsa ve uygulama, bitin hiçbir anlamı olmayan bir get... işlevini çağırırsa, bit yok sayılır.

Kullanıcı girdisi belirtilen koşullardan bir veya daha fazlasında başarısız olursa (sıfır değerlerine izin verilmediğinde sıfır değerinde olduğu gibi), AutoCAD bir mesaj görüntüler ve kullanıcıdan tekrar denemesini ister.

Anahtar Kelime Özellikleri

Dize argümanı aşağıdaki kurallara göre yorumlanır:

Her anahtar kelime, takip eden anahtar kelimeden bir veya daha fazla boşlukla ayrılır.

Örneğin, "Genişlik Yükseklik Derinlik" üç anahtar kelimeyi tanımlar.

Her anahtar kelime yalnızca harf, rakam ve tire (-) içerebilir.

Anahtar kelimeleri kısaltmanın iki yöntemi vardır:

1) Anahtar kelimenin gerekli kısmı büyük harflerle belirtilir ve anahtar kelimenin geri kalanı küçük harflerle belirtilir. Büyük harfli kısaltma anahtar kelimenin herhangi bir yerinde olabilir.

Örnek 1:

Genişlik yüKseklik deRinlik

Örnek 2:

Line lineType LAyer Color laYercolor

2) Tüm anahtar kelimeler büyük harflerle belirtilir ve hemen ardından bir virgül gelir, ardından da gerekli karakterler gelir.

Örnek 3:

LINE,L LINETYPE,T COLOR,C LINECOLOR,O

Eğer anahtar kelime tamamen büyük veya küçük harfle gösteriyorsa ve virgül ve ardından zorunlu bir kısım gelmiyorsa, AutoCAD anahtar kelimeyi yalnızca kullanıcı tamamını girdiğinde tanır.

Örnek 4:

Boş girişi engeller.

(initget 1 "Çizgi çEmber Yay")  ; Kullanıcı sadece belirlenen isimleri girebilir
(setq secim (getkword "Birini seçin [Çizgi/çEmber/Yay]: "))
(princ secim)

Örnek 5:

(initget 2) ; 0 açı girişini engeller
(setq aci (getangle "Döndürme açısını girin: "))

Örnek 6:

;1: boş girişi engeller
;2: 0 sayısı girişini engeller
;4: negatif sayı girişi engeller
(initget 7) ; 1+2+4=7
(setq sayi (getreal "Çember çapını girin: "))
(princ sayi)

10) getkword Fonksiyonu: Kullanıcıdan Anahtar Kelime Alma

getkword fonksiyonu, kullanıcıdan bir anahtar kelime (keyword) seçmesini sağlar. Bu fonksiyon, özellikle kullanıcının belirli seçenekler arasından birini seçmesi gereken durumlarda (örneğin, bir komutun alt seçeneklerini belirleme) oldukça kullanışlıdır. Kullanıcı, klavyeden bir anahtar kelime girebilir veya seçenekler arasında geçiş yapabilir.

getkword fonksiyonunu kullanmadan önce, initget fonksiyonu ile kullanıcının seçebileceği anahtar kelimeleri tanımlamanız gerekir. initget fonksiyonu, kullanıcının girdiğini kontrol eder ve sadece belirtilen anahtar kelimeleri kabul eder.

Kullanımı:

(getkword [mesaj])

mesaj (isteğe bağlı): Kullanıcıya gösterilecek mesajıdır. Bu mesaj, kullanıcıdan ne tür bir girdi beklendiğini açıklar.

Dönüş Değeri: Kullanıcının seçtiği anahtar kelimeyi döndürür. Kullanıcı seçim yapmadan Enter'e basarsa nil döner.

Örnek 1:

(initget "Evet Hayır")
(setq cevap (getkword "\nNesne silinsin mi? [Evet/Hayır]: "))
(princ cevap)

Kullanıcı fare ile açılan menüden seçim yapabilir.

Klavye ile;

e ev eve evet

veya 

h ha hay hayı hayır
kelimelerinden birini girerek seçim yapabilir. I harfi haricinde büyük küçük harf önemli değildir. I harfi büyükse büyük, küçükse küçük girilmelidir.

EVET evet Evet e E
girdilerinden biri girildiğinde Evet sonucunu verir.

HAYIR girişi kabul edilmez. I harfi menüdeki gibi küçük ı olarak girilmelidir.

H h Ha hay HAYı HAYıR girdileri kabul edilir. Hayır cevabı seçilmiş olur.

Örnek 2:

(initget "Çizgi ÇEmber ÇOkgen") ; Seçenekler
(setq secim (getkword "\nNesne türü [Çizgi/ÇEmber/çOkgen]: "))
(if secim
    ; Seçim yapıldıysa
    (princ (strcat "\nSeçiminiz: " secim))
    ; Seçim yapılmadıysa
    (princ "\nSeçim yapılmadı.")
)

Çizgi için Ç
Çember için ÇE
Çokgen için O
kısayolları kullanılabilir.

Örnek 3:

Boş girişi engeller. Bir seçenek seçilmesi zorunludur.

(initget 1 "Çizgi Çember ÇOkgen") ; Boş girişi engeller. Biri seçilmelidir
(setq secim (getkword "\nNesne türü [Çizgi/ÇEmber/çOkgen]: "))
; Seçim yapıldığında
(princ (strcat "\nSeçiminiz: " secim))

Örnek 4:

İşlem sırasında işlemden vazgeçme seçeneği sunar.

(initget "Çıkış")
(setq n1 (getpoint "Çember merkez noktası veya [Çıkış]:"))
(if (= n1 "Çıkış") ; Eğer kullanıcı "Çıkış" seçtiyse
    (princ "\nİşlem iptal edildi.")
    ; Eğer kullanıcı "Çıkış" seçmediyse
    (progn
        (initget 7) ; 1+2+4=7
        (setq r (getdist n1 "\nÇember yarıçapı girin: "))
        (command "_.CIRCLE" n1 r)
    )
)

Örnek 5:

Seçilen menü elemanına göre işlem yapar.

(defun test (/ secim n1 kenar yaricap)
  (while
    (progn
      (initget 1 "Kare Çember Üçgen Çıkış") ; Anahtar kelimeler tanımlanır
      (setq secim (getkword "\nBir şekil seçin [Kare/Çember/Üçgen/Çıkış]: "))
      (/= secim "Çıkış") ; Çıkış seçilmediyse döngü devam eder
    )
    (if (setq n1 (getpoint "\nŞeklin merkez noktasını seçin: "))
      ; Merkez noktası seçildiyse
      (progn
        ; Seçilen şekle göre işlem yap
        (cond
          ((= secim "Kare")
           (setq kenar (getdist n1 "\nKarenin kenar uzunluğu: "))
           (command "polygon" 4 n1 "I" kenar)
          )
          ((= secim "Çember")
           (setq yaricap (getdist n1 "\nÇemberin yarıçapı: "))
           (command "circle" n1 yaricap)
          )
          ((= secim "Üçgen")
           (setq kenar (getdist n1 "\nÜçgenin kenar uzunluğu: "))
           (command "polygon" 3 n1 "I" kenar)
          )
        )
        (princ "\nŞekil başarıyla çizildi!")
      )
      ; Merkez noktası seçilmediyse
      (princ "\nMerkez noktası seçilmedi.")
    )
  )
	; Çıkış seçildi
  (princ "\nProgram sonlandırıldı.")
)
(test)

11) getfiled Fonksiyonu. Kullanıcıdan Dosya Adı ve Yolunu Alma

Kullanıcıdan standart AutoCAD dosya iletişim kutusuyla bir dosya adı ister ve bu dosya adını döndürür. Bu fonksiyon, özellikle kullanıcının bir dosya açması, kaydetmesi veya bir dosya adı belirlemesi gereken durumlarda kullanışlıdır.

Kullanımı:

(getfiled Başlık Dosya-Adı Uzantı bit-değeri)

Başlık: Dosya seçim penceresinin başlığını belirler. "" ile boş giriş olabilir.

Örnek:

"Lütfen bir dosya seçin"

Dosya-Adı: Dosya seçme iletişim kutusunda varsayılan olarak görüntülenecek dosya adı. Bu parametre, kullanıcının daha önce kullandığı bir dosyayı hızlıca seçmesini sağlayabilir. "" ile boş giriş olabilir.

Örnekler:

"dosya1.dwg"

"c:/PROJELER/dosya1.dwg"

Uzantı: Dosya seçme iletişim kutusunda filtrelenecek dosya uzantısı. Bu, kullanıcının sadece belirli türde dosyaları görmesini sağlar. (örneğin "dwg" sadece uzantısı .DWG olan dosyaları listeler).

Varsayılan dosya adı uzantısı boş girilirse "", varsayılan olarak * (tüm dosya türleri) listelenir. Birden fazla uzantı belirtmek için "dwg;dxf;lsp;txt" veya "dwg;*" gibi kullanılabilir.

bit-değeri: Dosya seçme iletişim kutusunun davranışını kontrol eden bir tamsayı değeri. Aynı anda birden fazla koşul belirlemek için bit değerler toplanabilir.

Bit	Değer	Açıklama
0	1	Kaydedilecek yeni dosya adını belirler. Kullanıcı zaten var olan bir dosyayı seçerse, AutoCAD bir uyarı görüntüler ve işleme devam etme veya işlemi iptal etme seçeneği sunar. İletişim penceresinde Kaydet ve iptal butonları bulunur.
1	2
2	4	Kullanıcının istediği dosya adı uzantısını girmesine izin verir. Dosya adında uzantı yazılmazsa parametredeki Uzantı otomatik eklenir. İletişim penceresinde Aç,  iptal, Locate ve Find File butonları bulunur.
3	8	Bu bit ayarlanmışsa ve bit 0 ayarlanmamışsa, girilen dosya adı için bir kütüphane araması gerçekleştirir. Kütüphane arama yolunda dosyayı ve dizinini bulursa, yolu siler ve yalnızca dosya adını döndürür. (Aynı adlı bir dosyanın farklı bir dizinde olduğunu bulursa, yol silinmez.) İletişim penceresinde Aç,  iptal, Locate ve Find File butonları bulunur. bit 0 ayarlanmamışsa yalnız Kaydet ve iptal butonları bulunur.
4	16	Bu bit ayarlanmışsa veya varsayılan parametre bir yol sınırlayıcısıyla sonlanıyorsa (/ veya \\), parametre yalnızca bir yol adı olarak yorumlanır. Dosya adı kutusunu boş bırakır. İletişim penceresinde Aç,  iptal, Locate ve Find File butonları bulunur.
5	32	Bu bit ve bit 0 ayarlanırsa (yeni bir dosyanın belirtildiğini belirtir), kullanıcı var olan bir dosyanın üzerine yazmak üzere olduklarında uyarılmazlar. Var olan dosyanın üzerine yazılır.
6	64	Kullanıcı bir URL belirtirse uzak dosyayı aktarmaz.
7	128	URL'lere izin vermez.

Dönüş Değeri:

Bit değerlerine göre seçilen dosyanın adı veya tam yol ile adı döndürülür.

Örnek 1:

(getfiled "Dosya seç" "c:/program files/autodesk/autocad 2024/dosya1" "dxf" 1)

Kaydet tıklanırsa dönüş değeri:

"C:\\Program Files\\Autodesk\\AutoCAD 2024\\dosya1.dxf"

Kaydetme ile ilgili bir işlem yapılmaz. Bunun için ayrıca kodlar yazılmalıdır. Fonksiyonun görevi sadece dosya yolunu ve adını belirlemektir.

İptal tıklanırsa nil döner.

Örnek 2:

(getfiled "Dosya seç" "c:/program files/autodesk/autocad 2024/dosya1" "lsp" 2)

Aç tıklanırsa dönüş değeri ve dosya belirtilen klasörde varsa;

"C:\\Program Files\\Autodesk\\AutoCAD 2024\\dosya1.lsp"

Dosya yoksa dosyanın olmadığını belirten bir mesaj verir. Var olan bir dosyayı seçmesi beklenir.

İptal tıklanırsa nil döner.

Örnek 3:

(setq dosya (getfiled "Dosya Seç" "" "dwg" 0))
(if dosya
	(princ (strcat "\nSeçilen dosya: " dosya))
	(princ "\nDosya seçimi iptal edildi.")
)

Örnek 4:

(setq dosya (getfiled "Yeni Dosya Oluştur" "c:/windows/dosya1" "txt" 1))
(if	dosya
	(princ (strcat "\nOluşturulacak dosya: " dosya))
	(princ "\nDosya oluşturma iptal edildi.")
)

12) entsel Fonksiyonu: Kullanıcıdan Varlık (Entity) Seçimi

entsel (entity select)fonksiyonu, kullanıcıdan bir varlık (entity) seçmesini sağlar. Bu fonksiyon, çizimdeki nesneleri (örneğin, çizgiler, çemberler, yazılar ... vb.) seçmek ve bu nesnelerle ilgili bilgileri almak için kullanılır.

Kullanımı:

(entsel [mesaj])

mesaj (isteğe bağlı): Kullanıcıya gösterilecek mesajıdır. Bu mesaj, kullanıcıdan ne tür bir seçim yapması gerektiğini açıklar.

Dönüş Değeri:

Bir varlık seçilirse seçilen varlığın; entity name (varlık adı) ve seçim noktasını içeren bir liste döner.

entsel fonksiyonunun döndürdüğü liste, iki elemandan oluşur:

Entity Name: Seçilen varlığın AutoLISP'teki benzersiz tanımlayıcısıdır. Bu değer, varlıkla ilgili diğer işlemlerde (örneğin, entget ile özelliklerini okumak) kullanılır.

Seçim Noktası: Kullanıcının varlığı seçtiği noktanın koordinatlarını içeren bir liste (X, Y, Z).

Örnek 1:

(entsel)

(<Entity name: 7ef4f8c0> (10.0 20.0 0.0))

Varlık adı: 7ef4f8c0

Varlık seçilirken tıklanan nokta: (10.0 20.0 0.0)

İptal durumunda (bir varlık seçilmediyse) nil döner.

Örnek 2:

(setq secim (entsel "\nBir nesne seçin:"))
(if	secim
	(progn
		(setq varlik (car secim)) ; Varlık adı
		(setq koordinat (cadr secim)) ; Tıklama noktası
		(print (strcat "Seçilen nesne türü: " (cdr (assoc 0 (entget varlik)))))
		(princ "\nSeçim noktası: ")
		(princ koordinat)
		(princ)
	)
	(print "Nesne seçilmedi!")
)

Çıktı:

(<Entity name: 1967a3b8600> (37.7596 40.5403 0.0))
Seçilen nesne türü: CIRCLE
Seçim noktası: (37.7596 40.5403 0.0)

Örnek 3:

; Nesne özelliklerini listele
(vlax-dump-object (vlax-ename->vla-object (car (entsel "\nBir nesne seç"))) t)

Örnek 4:

; Seçilen çizginin başlangıç ve bitiş noktasını yaz
(setq secim (entsel "\nLütfen bir çizgi seçin: "))
(if secim
	(progn
		(setq varlik (car secim))  ; Varlık adı
		(setq ozellikler (entget varlik)) ; Varlığın özelliklerini al
		(setq baslangic (cdr (assoc 10 ozellikler))) ; Başlangıç noktası (10. grup kodu)
		(setq bitis (cdr (assoc 11 ozellikler))) ; Bitiş noktası (11. grup kodu)
		(princ "\nÇizginin başlangıç noktası: ")(princ  baslangic)
		(princ "\nÇizginin bitiş noktası: ")(princ bitis)
	)
	(princ "\nÇizgi seçimi iptal edildi.")
)

Örnek 5:

; Seçilen çizginin başlangıç ve bitiş noktasını yaz
(setq
	ent (car (entsel "\nÇizgi seç: "))
	baslangic (getpropertyvalue ent "StartPoint")
	bitis (getpropertyvalue ent "EndPoint")
)
(princ "\nÇizginin başlangıç noktası: ")(princ baslangic)
(princ "\nÇizginin bitiş noktası: ")(princ bitis)

13) nentsel Fonksiyonu: İç İçe Geçmiş Varlıkları Seçme

nentsel (nested entity select)fonksiyonu, kullanıcıdan bir varlık (entity) seçmesini sağlar. Ancak entsel fonksiyonundan farklı olarak, nentsel fonksiyonu, iç içe geçmiş varlıkları (nested entities) seçebilir. Bu, özellikle bloklar (blocks) veya bileşik nesneler (compound objects) içindeki varlıklarla çalışırken kullanışlıdır.

Kullanımı:

(nentsel [mesaj])

mesaj (isteğe bağlı): Kullanıcıya gösterilecek mesajıdır. Bu mesaj, kullanıcıdan ne tür bir seçim yapması gerektiğini açıklar.

Dönüş Değeri:

Seçilen varlıkla ilgili bilgileri içeren bir liste döner. Bu liste, aşağıdaki elemanlardan oluşur:

Entity Name: Seçilen varlığın AutoLISP'teki benzersiz tanımlayıcısı.

Seçim Noktası: Kullanıcının varlığı seçtiği noktanın koordinatları (X, Y, Z).

Dönüşüm Matrisi: Seçilen varlığın dönüşüm matrisi (transformation matrix). Bu matris, 4x4'lük bir listedir ve varlığın konumunu, ölçeğini ve dönüşünü tanımlar.

Üst Varlık Listesi: Seçilen varlığın içinde bulunduğu üst varlıkların listesi. Bu liste, en dıştaki varlıktan en içteki varlığa doğru sıralanır.

Kullanıcı seçim yapmazsa nil döner.

Örnek 1:

(nentsel "\nNesne seç: ")

Çıktı:

(<Entity name: 1967a3b8690> (195.937 78.9163 0.0)
((1.0 0.0 0.0) (0.0 1.0 0.0) (0.0 0.0 1.0) (0.0 0.0 0.0))
(<Entity name: 1967a3b86a0>))

Örnek 2:

entsel ve nentsel kullanımı

(while (setq ent (entsel "\nNesne seç: "))
	(print (strcat "Varlık türü: "
		(cdr (assoc 0 (entget (car ent)))))
	)
 )
 (while (setq ent (nentsel "\nVarlık veya alt varlık seç: "))
	(print (strcat "Varlık veya alt varlık türü: "
		(cdr (assoc 0 (entget (car ent)))))
	)
 )
(princ)

Örnek 3:

nentsel ile iç içe nesne seçimi ve özellikleri.

(setq secim (nentsel "\nLütfen bir varlık seçin: "))
(if secim
	(progn
		(setq varlik (car secim))  ; Entity name
		(setq nokta (cadr secim))  ; Seçim noktası
		(setq matris (caddr secim))  ; Dönüşüm matrisi
		(setq ust-varliklar (cadddr secim))  ; Üst varlık listesi
		(princ (strcat "\nSeçilen varlık: " (vl-princ-to-string varlik)))
		(princ (strcat "\nSeçim noktası: " (vl-princ-to-string nokta)))
		(princ (strcat "\nDönüşüm matrisi: " (vl-princ-to-string matris)))
		(princ (strcat "\nÜst varlık listesi: " (vl-princ-to-string ust-varliklar)))
	)
	(princ "\nVarlık seçimi iptal edildi.")
)

14) nentselp Fonksiyonu: İç İçe Geçmiş Varlıkları Seçme (Nokta ile)

nentselp (nested entity select point) fonksiyonu, nentsel fonksiyonuna benzer şekilde çalışır, ancak ek olarak bir nokta parametresi alabilir. Eğer nokta parametresi belirtilmezse, kullanıcıdan bir varlık seçmesi istenir ve seçilen varlıkla ilgili nentsel fonksiyonu gibi bir çıktı döner. Eğer nokta parametresi belirtilirse, kullanıcıdan seçim yapması istenmeden, belirtilen nokta konumundaki varlıkla ilgili nentsel fonksiyonu gibi bir çıktı döner.

Kullanımı:

(nentselp [nokta] [mesaj])

Örnek 1:

(nentselp "Nesne seç:" '(0 0))

--- Devam edecek ---
Kaynak: Kullanıcı Giriş Fonksiyonları Referansı (AutoLISP)